plugins {
    // Apply the java-library plugin to add support for Java Library
    id 'java-library'
    id 'maven'
    id 'signing'
}


group = "com.sigmaflare"
archivesBaseName = "binancej"
version = '1.0.4-SNAPSHOT'
ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

// Add default values for OSSRH
if (!project.hasProperty("ossrhUsername")) {
    ext.ossrhUsername = ""
}

if(!project.hasProperty("ossrhPassword")) {
    ext.ossrhPassword = ""
}


sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

dependencies {
    compile group: 'org.projectlombok', name: 'lombok', version: '1.16.20'
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-core', version: '2.9.5'
    compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.9.5'

    compile group: 'commons-io', name: 'commons-io', version: '2.6'
    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.5'

    testCompile 'junit:junit:4.12'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.18.3'
}

signing {
    sign configurations.archives
}


tasks.withType(Sign) {
    onlyIf { isReleaseVersion }
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'BinanceJ'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'A java implementation of the Binance API Specification'
                url 'https://git.xchg.sh/angrygoats/binancej'

                scm {
                    url 'https://git.xchg.sh/angrygoats/binancej'
                }

                licenses {
                    license {
                        name 'MIT License'
                        url 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id 'angrygoats'
                        name 'Taylor Bockman'
                        email 'tbockman@xchg.sh'
                    }
                }
            }
        }
    }
}